#! /bin/zsh

# This file: http://user.it.uu.se/~embe8573/conf/.zsh/files-fs
#            https://dataswamp.org/~incal/conf/.zsh/files-fs

# aliases
alias cp="cp -i -L -r"
alias dfh="df -h"
alias mkdir="mkdir -p"
alias mv="mv -i"
alias rm="rm -r"

find-symlinks () {
    local target=$1
    find $target -type l
}
alias find-links=find-symlinks

drop-dash-suffix () {
    local -a files
    files=($@)

    local -a words
    local name
    local ext
    local suffix

    local new
    for f in $files; do
        name=${f:r}
        ext=${f:e}
        if [[ $name != ${name#*-} ]]; then
            words=("${(@s/-/)name}")
            words[-1]=()
            new=$words[1]
            words[1]=()
            for w in $words; do
                new=${new}-${w}
            done
            new=${new}.${ext}
            mv -u $f $new
        fi
    done
}

find-duplicates () {
    local -a files
    files=($@)

    md5sum $files 2> /dev/null  |
        sort                    |
        awk '{ print $2,$1 }'   |
        uniq -c -f1             |
        grep -v '^  *1 '        |
        tr -s " "               |
        cut -d\  -f3
}

enumerate-files () {
    local -a files
    files=($@)

    local number=1
    local new_name
    local ext

    for f in $files; do
        if [[ -f $f ]]; then
            ext=${f:e}
            [[ $ext ]] && ext=.$ext
            new_name=$number$ext
            if [[ -f $new_name ]]; then
                files+=($f)
            else
                mv $f $new_name
            fi
            number=$(( $number + 1 ))
        else
            no-file-msg $f # http://user.it.uu.se/~embe8573/conf/.zsh/error
        fi
    done
}
alias enum-files=enumerate-files

change-extention () {
    local new_extention=$1
    shift

    local -a files
    files=($@)

    for f in $files; do
        if [[ -f $f ]]; then
            mv $f ${f:r}.$new_extention
        else
            no-file-msg $f
        fi
    done
}
alias change-ext=change-extention

create-sized-file () {
    local size=$1
    local name=${2:-random-$size}
    head -c $size < /dev/urandom > $name
    ls -b -l $name
}
alias {csf,sf}=create-sized-file

touch () {
    local -a files
    files=($@)

    local last=$files[-1]

    for f in $files; do
        /usr/bin/touch $f
    done

    store-file-path $last
}

recent-files () {
    local hits=${1:-10}
    find -type f -printf "%C@ %p\n" | sort -rn | head -n $hits
}
alias newest-{files,file}=recent-files

dir-size () {
    local -a dirs
    dirs=($@)

    local options='-hs'
    [ $# -gt 1 ] && options+='c'

    { [ -w . ] && du $options $dirs ||
             sudo du $options $dirs 2> /dev/null } |
        sort -rh |
        head -n 10
}
alias dirsize=dir-size

list-directories () {
    local -a files
    files=($(ls -1d */))
    dir-size $files
}
alias ldirs=list-directories

biggest-files () {
    local num_files=${1:-10}
    local where=${2:-./}
    local du_options=-ahS

    if [ -w $where ]; then
             du $du_options $where
    else
        sudo du $du_options $where 2> /dev/null
    fi |
        sort -hr |
        head -n $num_files
}

alias lns='ln -s'

identical-files () {
    local file_1=$1
    local file_a=$2

    cmp --silent $file_1 $file_a \
        && echo "identical" \
            || echo "different"
}

clean-filename () {
    local -a files
    files=($@)

    local new_name
    local ext
    local lowercased

    local -a buzzwords
    buzzwords=(1080p 720p edit hd mix movie official \
                     original remix the version \
                     video)

    for f in $files; do
        if [[ -f $f || -d $f ]]; then
            # get lowercased base and extention
            lowercased=${f:l}
            new_name=${lowercased:r}
            ext=${lowercased:e}

            # drop buzzwords
            local b
            for b in $buzzwords; do
                new_name=${new_name//$b/} # BUG: here, make sure
            done                          #      it isn't a word part!

            # (multi-char) word delimiter -> (a single) dash
            new_name=${new_name//[-:_ ]##/-}

            # drop initial dash
            new_name=${new_name/#-/}

            # drop non-alphanums
            new_name=${new_name//[^a-z0-9-]/}

            # reinsert extention
            [[ -n $ext ]] && new_name=$new_name.$ext

            # misc
            new_name=${new_name//-.$ext/.$ext}   # - and . -> .
            new_name=${new_name//ü/u}            #       ü -> u
            new_name=${new_name//&/and}          #       & -> and

            mv $f $new_name # 2> /dev/null
            echo "Moved $f to $new_name"
        fi
    done
}
alias fix-filename=clean-filename
alias clean-filenames='clean-filename *'

count-word-in-files () {
    local word=$1
    shift

    local -a files
    files=($@)

    for f in $files; do
        (( $(grep $word < $f | wc -l) )) && echo $f
    done
}

count-files () {
    find ./ -type f | wc -l
}
alias files=count-files

count-all () {
    find ./         | wc -l
}

find-file-dwim () {
    local name=$1

    local in_path=$(pwd | grep $USER)
    if [[ -z $in_path ]]; then
        sudo find / -name $name
    else
        find ~ -name $name
    fi
}
alias ff=find-file-dwim

find-file-substring () {
    local name=$1
    sudo find / -name \*$name\*
}
alias ffs=find-file-substring

most-recent-modify () {
    local num_files=${1:-10}
    /bin/ls -dt ${PWD}/* | head -n $num_files
}
alias mr=most-recent-modify

most-recent-access () {
    local num_files=${1:-10}
    /bin/ls -du ${PWD}/* | head -n $num_files
}
alias mra=most-recent-access