(require 'sudo-user-path)
(require 'window-new)

(defalias 'lowercase-region 'downcase-region)

(defun find-here ()
  (interactive)
  (let ((start (point)))
    (goto-char (point-min))
    (if (search-forward-regexp (format "%s [[:digit:]]" comment-start)
                                 (point-max)
                                 t) ; NOERROR
        (beginning-of-line-at-top)
      (progn
        (message "No `find-here' mark in this buffer!")
        (goto-char start) ))))

(defun remove-wiki-notes ()
  (interactive)
  (while (re-search-forward "\\^\\[[[:digit:]]* ?\\]" (point-max) t) ; NOERROR
    (replace-match "") ))

(defun add-to-digits (term)
  (interactive "p")
  (while (re-search-forward "[0-9]+" nil t) ; BOUND NOERROR
    (let*((digit (string-to-number (match-string 0)))
          (sum (+ digit term)) )
      (replace-match (format "%s" sum)) )))

;; (setq before-save-hook nil)
(defun before-save-hook-f ()
  (delete-trailing-whitespace) )
(setq before-save-hook #'before-save-hook-f)

(defun back-to-dwim ()
  (interactive)
  (let ((point (point)))
    (back-to-indentation)
    (when (= point (point))
      (beginning-of-line) )))

(defun replace-regexp-save-excursion (regexp to-string)
  (interactive "sregexp: \nsto-string: ")
  (save-excursion
    (let*((scope
           (if mark-active (list (mark)  (point) )
                           (list (point) (point-max)) ))
          (start (car  scope))
          (end   (cadr scope)) )
      (goto-char start)
      (while (re-search-forward regexp end t) ; NOERROR
        (replace-match to-string t nil) ))))  ; FIXEDCASE LITERAL

(defalias 'rr 'replace-regexp-save-excursion)

(defun fix-region-or-buffer ()
  "Indent (according to `indent-region-function'),
then do `font-lock-fontify-buffer'."
  (interactive)
  (let*((scope (if mark-active
                   (list (mark)      (point) )
                   (list (point-min) (point-max)) ))
        (min (nth 0 scope))
        (max (nth 1 scope)) )
    (indent-region min max) )
  (font-lock-fontify-buffer) )

(require 'dired)
(defun su-edit ()
  "Edit the current buffer file as superuser."
  (interactive)
  (let*((window-start (window-start))
        (point        (point))
        (mark         (when mark-active (mark)))
        (path         (or dired-directory (file-truename (buffer-file-name) )))
        (sudo-path    (sudo-user-path path)) )
    (find-alternate-file sudo-path)
    (when mark (set-mark mark))
    (goto-char point)
    (when dired-directory (dired-previous-line 1))
    (set-window-start nil window-start) ; the selected WINDOW
    ))

(provide 'edit)