;;; -*- lexical-binding: t -*-
;;
;; this file:
;;   https://dataswamp.org/~incal/emacs-init/bibtex/bibtex-next-volume.el
;;
;; requires:
;;   https://dataswamp.org/~incal/emacs-init/bibtex/bibtex-autokey-insert.el
;;   https://dataswamp.org/~incal/emacs-init/bibtex/bibtex-book.el
;;   https://dataswamp.org/~incal/emacs-init/isbn-verify.el
;;
;; To test, uncomment the below entry (named "berserk-23"),
;; move point above it, and do
;;
;;   M-x next-book RET RET RET RET RET RET
;;
;; @book{berserk-23,
;;   author     = {Kentaro Miura},
;;   isbn       = {978-1-59307-864-5},
;;   publisher  = {Dark Horse},
;;   title      = {Berserk 23},
;;   year       = {2008}
;; }
;;
;; This will insert the following entry, which indeed is the
;; next book in the series:
;;
;; @book{berserk-24,
;;   author     = {Kentaro Miura},
;;   isbn       = {978-1-59307-865-2},
;;   publisher  = {Dark Horse},
;;   title      = {Berserk 24},
;;   year       = {2008}
;; }

(require 'bibtex)
(require 'bibtex-autokey-insert)
(require 'bibtex-book)
(require 'cl-lib)
(require 'isbn-verify)

(defun title-next (title)
  (when (string-match "\\(.+\\) \\([[:digit:]]+\\)" title)
    (let*((name     (match-string 1 title))
          (vol      (match-string 2 title))
          (vol-next (read-number "Volume: " (1+ (string-to-number vol)))) )
      (format "%s %s" name vol-next) )))
;; (title-next "Berserk 23") ; Berserk 24

(defun isbn-13-bibtex-entry-get-isbn ()
  (let ((isbn-13 (bibtex-autokey-get-field "isbn-13")))
    (if (not (string= isbn-13 ""))
        isbn-13
      (let*((isbn (bibtex-autokey-get-field "isbn"))
            (len  (length (string-join (split-string isbn "-")))) )
        (if (= 13 len)
            isbn
          (error "Not and ISBN-13 (length %s)" len) )))))

(defun isbn-13-field (isbn field &optional field-stop)
  (let*((beg  (1- field))
        (end  (or field-stop field))
        (sep  "-")
        (subl (cl-subseq (split-string isbn sep) beg end)) )
    (if (= 1 (length subl))
        (car subl)
      (string-join subl sep) )))
;; (isbn-13-field "978-1-59307-864-5" 1)   ; 978
;; (isbn-13-field "978-1-59307-864-5" 1 4) ; 978-1-59307-864

(defun isbn-13-publisher (isbn)
  (let ((pub (isbn-13-field isbn 3)))
    (read-string "Publisher: " pub) ))
;; (isbn-13-publisher "978-1-59307-864-5") ; 59307

;; (string-pad "980" 5 ?0 t)

(defun isbn-13-publication (isbn)
  (isbn-13-field isbn 4) )
;; (isbn-13-publication "978-1-59307-864-5")
;; (isbn-13-publication "978-1-9747-0937-3")

(defun isbn-13-publication-next (isbn)
  (let*((pub      (isbn-13-publication isbn))
        (pub-len  (length pub))
        (pub-next (string-pad
                    (number-to-string (1+ (string-to-number pub)))
                    pub-len ?0 t) ))
    (read-string "Publication: " pub-next) ))
;; (isbn-13-publication-next "978-1-59307-864-5") ; 865
;; (isbn-13-publication-next "978-1-9747-0937-3")

(defun isbn-13-next (isbn)
  (let*((but-last    (format "%s-%s-%s" (isbn-13-field isbn 1 2)
                                        (isbn-13-publisher isbn)
                                        (isbn-13-publication-next isbn) ))
        (check-digit (read-number "Check digit: " (isbn-verify but-last))) )
    (format "%s-%s" but-last check-digit) ))
;; (isbn-13-next "978-1-59307-864-5") ; 978-1-59307-865-2
;; (isbn-13-next "978-1-9747-0937-3") ; 978-1-9747-0938-0

(defun new-book-next ()
  (interactive)
  (let ((beg (point)))
    (when (bibtex-next-entry)
      (let ((author    (bibtex-autokey-get-field "author"))
            (isbn      (isbn-13-bibtex-entry-get-isbn))
            (publisher (bibtex-autokey-get-field "publisher"))
            (title     (bibtex-autokey-get-field "title"))
            (year      (string-to-number (bibtex-autokey-get-field "year") )))
        (unless (and author isbn publisher title year)
          (error "Incomplete Bibtex entry") )
        (let*((isbn-new  (isbn-13-next isbn))
              (title-new (title-next title))
              (year-new  (read-number "Year: " year)) )
          (goto-char beg)
          (create-book author isbn-new publisher title-new year-new)
          (bibtex-autokey-insert-check-isbn)
          (goto-char beg) )))))

(defalias 'next-book #'new-book-next)

(provide 'bibtex-next-volume)